home *** CD-ROM | disk | FTP | other *** search
/ CD Actual 80 / CD Actual 80 Julio-Agosto 2003.iso / Linux / LinuxGazette / lg / issue22 / stdlib.m4 < prev    next >
Encoding:
Text File  |  2002-08-14  |  5.4 KB  |  175 lines
  1. m4_divert(-1)
  2.  
  3. m4_define(`_Copyleft',
  4. `Copyright (C) 1997 Bob Hepple
  5.  
  6. This program is free software; you can redistribute it
  7. and/or modify it under the terms of the GNU General Public
  8. License as published by the Free Software Foundation; either
  9. version 2 of the License, or (at your option) any later
  10. version.
  11.  
  12. This program is distributed in the hope that it will be
  13. useful, but WITHOUT ANY WARRANTY; without even the implied
  14. warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15. PURPOSE.  See the GNU General Public License for more
  16. details.
  17.  
  18. You should have received a copy of the GNU General Public
  19. License along with this program; if not, write to the Free
  20. Software Foundation, Inc., 675 Mass Ave, Cambridge, MA
  21. 02139, USA.')
  22.  
  23. m4_changecom(`[[[[')
  24.  
  25. m4_dnl define(`_LOCAL',1)
  26.  
  27. m4_ifdef(`_LOCAL',
  28.   `m4_define(`_HOMEPAGE',`//127.0.0.1/~bhepple')',
  29.   `m4_define(`_HOMEPAGE',`//www.bit.net.au/~bhepple')')
  30.  
  31. m4_ifdef(`_LOCAL',
  32.   `m4_define(`_SECONDPAGE',`//127.0.0.1/~bhepple')',
  33.   `m4_define(`_SECONDPAGE',`//www.bit.net.au/~bhepple')')
  34.  
  35. m4_define(`_EMAIL_ADDRESS',bhepple@bit.net.au)
  36.  
  37. m4_define(`_MAILTO',<A HREF="mailto:$1">$2</A>)
  38.  
  39. m4_define(`_EMAILME',_MAILTO(_EMAIL_ADDRESS,$1))
  40.  
  41. m4_define(`_CODEQUOTE',<BLOCKQUOTE><PRE><CODE>$1</CODE></PRE></BLOCKQUOTE>)
  42.  
  43. m4_dnl Logical markup:
  44.  
  45. m4_define(`_EM',<EM>$1</EM>)
  46. m4_define(`_STRONG',<STRONG>$1</STRONG>)
  47. m4_define(`_CITE',<CITE>$1</CITE>)
  48. m4_define(`_PRE',<BLOCKQUOTE><PRE>$1</PRE></BLOCKQUOTE>)
  49. m4_define(`_CODE',<CODE>$1</CODE>)
  50.  
  51. m4_dnl Physical markup:
  52.  
  53. m4_define(`_BOLD',<B>$1</B>)
  54. m4_define(`_ITALICS',<I>$1</I>)
  55. m4_define(`_STRIKE',<S>$1</S>)
  56. m4_define(`_SUBSCRIPT',<SUB>$1</SUB>)
  57. m4_define(`_SUPERSCRIPT',<SUP>$1</SUP>)
  58. m4_define(`_COURIER',<TT>$1</TT>)
  59. m4_define(`_UNDERLINE',<U>$1</U>)
  60. m4_define(`_SMALL',<SMALL>$1</SMALL>)
  61. m4_define(`_BIG',<BIG>$1</BIG>)
  62.  
  63. m4_define(`_CENTER',<CENTER>$1</CENTER>)
  64.  
  65. m4_define(`_LIMAGE', <IMG SRC="$1" ALT="[$1]" WIDTH=$2 HEIGHT=$3>)
  66.  
  67. m4_define(`_RIMAGE', <IMG SRC="$1" ALT="[$1]" WIDTH=$2 HEIGHT=$3 ALIGN="right">)
  68.  
  69. m4_define(`_IMAGE', <P><CENTER><IMG SRC="$1" ALT="[$1]" WIDTH=$2 HEIGHT=$3></CENTER><P>)
  70.  
  71. m4_define(`_IMAGE2',<P><CENTER>
  72. <IMG SRC="$1" ALT="[$1]" ALIGN=TOP WIDTH=$2 HEIGHT=$3>
  73. <IMG SRC="$4" ALT="[$4]" ALIGN=TOP WIDTH=$5 HEIGHT=$6>
  74. </CENTER><P>)
  75.  
  76. m4_define(`_FTP',<A HREF="http:$1">$2</A>)
  77.  
  78. m4_define(`_HEAD1', <H2>$1</H2>)
  79.  
  80. m4_define(`_HEAD2', <H3>$1</H3>)
  81.  
  82. m4_define(`_LINK', <a href="$1">$2</a>)
  83.  
  84. m4_define(`_SELFLINK', _LINK($1,$1))
  85.  
  86. m4_define(`_LOCALLINK',<A HREF="#$1">$2</A>)
  87.  
  88. m4_define(`_LABEL',<A NAME="$1"><H2>$1</H2></A>)
  89.  
  90. m4_define(`_LINK_TO_LABEL', _LOCALLINK($1,$1))
  91.  
  92. m4_define(`_PLUG',
  93.   _LINK(http://www.ssc.com/linux/,
  94.     _IMAGE(_HOMEPAGE/powered.gif,196,49))<BR>
  95. `If you are wondering, Linux is a free, non-commercial
  96. operating system for computers. It happens to be a hobby of
  97. mine and might well interest other hackers. Click on the logo
  98. to learn more...')
  99.  
  100. m4_define(`_HEADER', 
  101. <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 3.2//EN">
  102. <HTML> 
  103. <HEAD> 
  104.   <TITLE>$1</TITLE>
  105.   <META NAME="Author" CONTENT="Bob Hepple">
  106. </HEAD>
  107. <BODY BGCOLOR="#FFFFFE" BACKGROUND="http:_HOMEPAGE/bg.gif" $2>
  108. <CENTER><A NAME="Contents"><H1>$1</H1></A></CENTER><HR>)
  109.  
  110. m4_define(_COUNTER,)
  111.  
  112. m4_dnl define(`_COUNTER',<img SRC="/cgi-bin/Count.cgi?dd=T|ft=6|frgb=648bd8|md=5|pad=Y|df=bhepple$1.dat" align=absmiddle> $2)
  113.  
  114. m4_define(`_CREDITS',`For corrections/additions/suggestions for this page, please send email to: _EMAILME(Bob Hepple) <P> Copyright `©' 1997 Bob Hepple. All rights reserved.')
  115.  
  116. m4_dnl ----------------------------------------------
  117. m4_dnl TABLE OF CONTENTS
  118.  
  119. m4_define(`_Start_TOC',`<UL><P>m4_divert(-1)
  120.   m4_define(`_H1_num',0)
  121.   m4_define(`_H2_num',0)
  122.   m4_define(`_H3_num',0)
  123.   m4_define(`_H4_num',0)
  124.   m4_divert(1)')
  125.  
  126. m4_define(`_H1', `m4_divert(-1)
  127.   m4_define(`_H1_num',m4_incr(_H1_num))
  128.   m4_define(`_H2_num',0)
  129.   m4_define(`_H3_num',0)
  130.   m4_define(`_H4_num',0)
  131.   m4_define(`_TOC_label',`_H1_num. $1')
  132.   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
  133.   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
  134.  
  135. m4_define(`_H2', `m4_divert(-1)
  136.   m4_define(`_H2_num',m4_incr(_H2_num))
  137.   m4_define(`_H3_num',0)
  138.   m4_define(`_H4_num',0)
  139.   m4_define(`_TOC_label',`_H1_num._H2_num $1')
  140.   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
  141.   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
  142.  
  143. m4_define(`_H3', `m4_divert(-1)
  144.   m4_define(`_H3_num',m4_incr(_H3_num))
  145.   m4_define(`_H4_num',0)
  146.   m4_define(`_TOC_label',`_H1_num._H2_num._H3_num $1')
  147.   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
  148.   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
  149.  
  150. m4_define(`_H4', `m4_divert(-1)
  151.   m4_define(`_H4_num',m4_incr(_H4_num))
  152.   m4_define(`_TOC_label',`_H1_num._H2_num._H3_num._H4_num $1')
  153.   m4_divert(0)<LI><A HREF="#_TOC_label">_TOC_label</A>
  154.   m4_divert(1)<A NAME="_TOC_label"><H2>_TOC_label</H2></A>')
  155.  
  156. m4_define(`_End_TOC',`m4_divert(0)</UL><P>')
  157.  
  158. m4_dnl ----------------------------------------------
  159. m4_dnl TABLES
  160.  
  161. m4_dnl _Start_Table(Columns,TABLE parameters)
  162. m4_dnl defaults are BORDER=1 CELLPADDING="1" CELLSPACING="1"
  163. m4_dnl WIDTH="n" pixels or "n%" of screen width
  164. m4_define(`_Start_Table',`<TABLE $1>')
  165.  
  166. m4_define(`_Table_Hdr_Item', `<th>$1</th>m4_ifelse($#,1,,`_Table_Hdr_Item(m4_shift($@))')')
  167.  
  168. m4_define(`_Table_Row_Item', `<td>$1</td>m4_ifelse($#,1,,`_Table_Row_Item(m4_shift($@))')')
  169.  
  170. m4_define(`_Table_Hdr',`<tr>_Table_Hdr_Item($@)</tr>')
  171. m4_define(`_Table_Row',`<tr>_Table_Row_Item($@)</tr>')
  172.  
  173. m4_define(`_End_Table',</TABLE>)
  174.  
  175. m4_divert